Remplir un combobox avec les champs d'une table mySQLRésolu

Question

Bonjour,

Es t-il possible de remplir un ComboBox avec les champs une table mySQL ?

Il me semble qu'on peut faire un truc du genre :

sqlstr = "SELECT * FROM " & cbxListeTable ' extracts all data

conn.Open sqlstr

Mais ensuite je suis perdu pour ce qui est de placer tout sa dans un ComboBox.

Merci d'avance !

Renfield · Answer

te faut remplir un Recordset avec tes données, et faire une en gros:

With conn.Open("SELECT `champ1` FROM " & cbxListeTable)
    Do Until .EOF
        cbxData.AddItem .Fields("champ1").Value
        .MoveNext
    Loop
    .Close
End With


Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Merci de te réponse,

L'exemple que tu ma donner ajoute "champ1" dans cbxData ? 

J'ai essayer, mais un problème vien quand on fais "conn.Open(...." il n'accèpte pas..

Merci d'avance

Renfield · Answer

remplace Open par Execute
j'ai repris bêtement ce que tu as ecrit...

la méthode Open de la connection ouvre la connexion a proprement parler, en exploitant la connectionString

pour récupérer un recordset, c'est pas là ^^

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Bonjour,

J'ai réussi à faire comme vous avez dit, mais le problème est que maintenant dans mon combobox je récupère les enregistrements des champs, et moi j'aurai voulu résupérer juste les champs de la table :) 

Quelqu'un à une idée ? 


Merci d'avance

Renfield · Answer

le nom des champs tu veux dire ?

faire un OpenSchema (voir doc MSDN)

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Ok merci beaucoup,

J'avais déjà éffectuer cette commande, mais pour afficher mes tables :

cbxListeTable.Clear

Dim strListeTable As String

Set rstSchema = conn.OpenSchema(adSchemaTables)
    
    Do Until rstSchema.EOF
    
        strListeTable = rstSchema.Fields("TABLE_NAME")
        'ComboBox1.Value = strListeTable
        cbxListeTable.AddItem (strListeTable)
    
        rstSchema.MoveNext
    Loop

J'ai essayer de remplacer TABLE_NAME par FIELD_NAME, mais sa ne marche pas, faut-il encore changer autre chose ?

Merci

Renfield · Answer

euh...

en fait, tu n'a pas lu la doc, si ?




Renfield - Admin CodeS-SourceS - MVP Visual Basic

Renfield · Answer

Allez, je te mache la chose :
Private moConn As Connection

Private Sub CcLstTables_Click()
    If CcLstTables.ListIndex <> -1 Then
        CcLstFields.Clear
        With moConn.OpenSchema(adSchemaColumns, Array(Empty, Empty, CcLstTables.Text))
            Do Until .EOF
                CcLstFields.AddItem .Fields("COLUMN_NAME")
                .MoveNext
            Loop
            .Close
        End With
    End If
End Sub

Private Sub Form_Load()
    Set moConn = New Connection
    moConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\a.mdb"
    
    CcLstTables.Clear
    With moConn.OpenSchema(adSchemaTables)
        Do Until .EOF
            CcLstTables.AddItem .Fields("TABLE_NAME")
            .MoveNext
        Loop
        .Close
    End With
    If CcLstTables.ListCount Then
        CcLstTables.ListIndex = 0
    End If
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    moConn.Close
End Sub


Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Haa super, 

j'avais essayer se fameux "COLUMN_NAME", mais je l'avais marquer faux :S

Je vais me débrouiller pour la suite :)

Merci beaucoup !

Renfield · Answer

le tout est de bien écrire les contraintes ; ici le TABLE_NAME :

With moConn.OpenSchema(adSchemaColumns, Array(Empty, Empty, CcLstTables.Text))

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Bonjour,

J'ai denouveau un petit  problème..tout marchais bien jusqu'à aujourd'hui, losque que je click sur un element de mon combobox il me resort dans un autre combobox tout les champs de toute les tables...je sais pas pourquoi sa fais cela tout d'un coup ! Voici le code,

ComboBox2.Clear

Dim strListeChamp As String

Set rstSchema = conn.OpenSchema(adSchemaColumns)
    
    Do Until rstSchema.EOF
    
        ComboBox2.AddItem (rstSchema.Fields("COLUMN_NAME"))
    
        rstSchema.MoveNext
    Loop

Merci d'avance !

Renfield · Answer

voir mon commentaire ci dessus...

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

J'ai essayer de mettre cette contrainte, mais sa ne marche pas, comment avec sa on dire "Je veux les champs de cette table" ? 

lbxChamp = ""

Dim strChamp As String

'Set rstSchema = conn.OpenSchema(adSchemaColumns, Array(Empty, Empty, CcLstTables.Text))

If cbxListeTable.ListIndex <> -1 Then

    With conn.OpenSchema(adSchemaColumns, Array(Empty, Empty, cbxListeTable.Text))
    
        Do Until .EOF
    
            strChamp = rstSchema.Fields("COLUMN_NAME")
  
            lbxChamp.AddItem (strChamp)
    
            rstSchema.MoveNext
        Loop
    End With
End If


Merci

Renfield · Answer

comme cela, mais en évitant d'utiliser 

rstSchema

qui est rempli je ne sais où

comme dans mon code :


If cbxListeTable.ListIndex <> -1 Then 
    With conn.OpenSchema(adSchemaColumns, Array(Empty, Empty, cbxListeTable.Text)) 
        Do Until .EOF 
           lbxChamp.AddItem .Fields("COLUMN_NAME") 
           .MoveNext 
        Loop 
    End With 
End If 



Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Ok,

J'essaie et je vous redit ! :)

merci beaucoup !

cs_Fred2468 · Answer

Super sa marche impec ;-) 

Merci beaucoup !

cs_Fred2468 · Answer

Bonjour bonjour,

J'ai un message d'erreur que j'arrive pas à résoudre, le voici :

Le type ne correspond pas.

Ce message surviens quand j'essaye d'afficher tout les enregistrements d'une table que je sélectionne dans une listebox. Cela marche quand j'ajoute UN SEUL enregistrement dans toute ma table, mais lorsque que j'ajoute un autre enregistrement dans nimporte quelle champ de ma table sélectionner, HOP sa plante avec se message d'erreur.. voici mon bout de code :

lbxEnre.Visible = True

lbxEnre.Clear


Dim strEnreg As String

strEnreg = lbxChamp.Value

With conn.Execute("SELECT " & strEnreg & " FROM " & ListeTable.Value)
    Do Until .EOF
        lbxEnre.AddItem .Fields(strEnreg).Value
        .MoveNext
    Loop
    .Close
End With

Si vous avez une solution ?

Merci d'avance

Renfield · Answer

tu devrais échapper les noms :

("SELECT `" & strEnreg & "` FROM `" & ListeTable.Value & "` ")

gaffe, c'est pas des ' mais bien des `  (alt gr + 7)

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Merci,

J'ai essayer ce que tu ma dit, de tout séparer correctement, mais aucun chamgement, que je me met en mode Debug, l'erreur surviens lorsqu'il exécute cette ligne :

lbxEnre.AddItem .Fields(strEnreg).Value 

Je pense que le problème viens de la variable "strEnreg" car j'ai mis à l'intérieur le champs séléctionner.

Merci d'avance

Renfield · Answer

non, ca ne doit pas venir de là
tu pourrais mettre 0, d'ailleurs, pour exploiter le premier (et seul) champ extrait de la base de données.

a voir la donnée a ajouter...

remplace lbxEnre par MsgBox, pour tester  :

MsgBox .Fields(0).Value

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Malheureusement pas beaucoup changement, si ce n'est que le message d'erreur à changer :

Utilisation incorrecte de Null

Si tu n'a pas d'autre solution, je vais essayer de me dépatouiller :)

Merci de tes réponse !

Renfield · Answer

tu as donc ta réponse...
c'est bien ce que je soupsonnais, pour ca que je t'ai dit d'utiliser un MsgBox

tu as dans ta table des champs VIDES 
pas une chaine vide "" mais bien une valeur NULL

et ni le AddItem ni le MsgBox n'aprecient franchement...

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Donc je suis obliger de tout remplir ma table pour qu'il n'y ai pas de "Null" ? 

Je ne vois pas comment faire !

Renfield · Answer

tu peux aussi zapper ces champs grace à une clause WHERE dans ta requete...

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Pas bête... je vais essayer de me renseigner :) 

Je vous redonne des news ;-)

cs_Fred2468 · Answer

Voilà donc j'ai trouver mon principal problème. Quand je visionne ma table dans mySQL on voit que ma table est rempli de "NULL" mise à par ceux qui sont rempli et le problème vien alors quand je créer ma table avec mon programme. Voici comment je créer :


If conn.State = 1 Then

Dim Champ_1 As String, Champ_2 As String
Dim Champ_3 As String, Champ_4 As String
Dim Champ_5 As String, Champ_6 As String
Dim Numero As String

Champ_1 = tbxChamp1.Value
Champ_2 = tbxChamp2.Value
Champ_3 = tbxChamp3.Value
Champ_4 = tbxChamp4.Value
Champ_5 = tbxChamp5.Value
Champ_6 = tbxChamp6.Value
Numero = "numero"

sqlstr = "CREATE TABLE " & tbxNomTable & "(" _
& Numero & " " & "int(10) PRIMARY KEY AUTO_INCREMENT" & "," _
& Champ_1 & " " & Type1.Value & "," _
& Champ_2 & " " & Type2.Value & "," _
& Champ_3 & " " & Type3.Value & "," _
& Champ_4 & " " & Type4.Value & "," _
& Champ_5 & " " & Type5.Value & "," _
& Champ_6 & " " & Type6.Value _
& ")"


conn.Execute sqlstr

MsgBox "Données ajoutées avec succès !", vbMsgBoxRight, "Information"

Else

MsgBox "Impossible d'éffectuer cette opération, vous n'êtes pas connecter à la base !", vbCritical, "Attention"

End If

Voilà donc le problème c'est qu'avec ce code je suis obliger de créer 6 tables mais le problème c'est que quand ma table se créer avec ses 6 enregistrement, je crois qu'il ajoute deja des donnée (NULL) enfin je pense..

Merci

Renfield · Answer

avoir NULL n'est en soit pas forcément génant...

ca autorise une donnée a ne pas être renseignée.

le tout est de gérer correctement les cas où cette donnée est manquante


Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Fred2468 · Answer

Enfaite le problème viens plutôt quand j'ajoute mes données ! 

If conn.State = 1 Then

sqlstr = "INSERT INTO " & cbxListeTable & " SET " _
& ComboBox2.Value & " = '" & tbxEnregistrement & "'"
conn.Execute sqlstr


Label24 = tbxEnregistrement & " à été ajouté au champ " & ComboBox2.Value

Else

MsgBox "Impossible d'éffectuer cette opération, vous n'êtes pas connecter à la base !", vbCritical, "Attention"

End If


Je sais pas comment faire pour dire : J'ajoute une donnee dans le champ1 et le reste je mais "vide" un truc du genre :

INSERT INTO `atelier`.`personne` (
`numero` ,
`Nom` ,
`Prenom` ,
`Adresse` ,
`Telephone` ,
`Site` 
)
VALUES (
NULL , 'TEst455', '', '', '', ''
);


Faut que je trouve un moyen de détecter quelle dans quelle champ j'ai ajouter...

Merci

cs_Fred2468 · Answer

Problème plus ou moin résolu ! 

Quand je créer ma table, j'ai indiquer que les champs étais "NOT NULL" de cette manière et sa fonctionne :) 

NotNull = "NOT NULL"

sqlstr = "CREATE TABLE " & tbxNomTable & "(" _
& Numero & " " & "int(10) PRIMARY KEY AUTO_INCREMENT" & "," _
& Champ_1 & " " & Type1.Value & " " & NotNull & "," _
& Champ_2 & " " & Type2.Value & " " & NotNull & "," _
& Champ_3 & " " & Type3.Value & " " & NotNull & "," _
& Champ_4 & " " & Type4.Value & " " & NotNull & "," _
& Champ_5 & " " & Type5.Value & " " & NotNull & "," _
& Champ_6 & " " & Type6.Value & " " & NotNull & ")"

Merci !

Remplir un combobox avec les champs d'une table mySQL

29 réponses

Votre réponse

Discussions similaires