[Déplacé .Net -- VBS] [VBS] supprimer une liste de fichiers.Résolu

Question

Bonjour à tous, j'ai créé un script qui recherche certains fichiers sur l'ordinateur, et les liste dans un raport au format .txt

les chemins complets des fichiers sont listés dans le rapport et le contenu du rapport se présente comme ceci:

c:\documents and settings\zatox\mes documents\programmation\VBS	est.exe
c:\documents and settings\zatox\bureau\sécurité\fichier2.exe
c:\documents and settings\zatox\bureau\check	est.bat
d:\autorun.inf
e:\jeux\PES6.exe


hélas mes compétences en programmation sont limitées, pouvez vous m'aider a créer un script qui irait chercher le rapport .txt et supprimmerait les fichiers listés dans ce rapport.


Merci d'avance.
http://pc-system.fr

cs_JMO · Accepted Answer

Bonsoir,



Il te suffit:
- tester l'existence du fichier en entrée;
- lire ligne à ligne et supprimer le fichier s'il existe;

Option Explicit

Call FnDeleteFile("D:\Test.txt")
 
Function FnDeleteFile(strFile)
   Dim objFso, objTextStream
   Dim strLine
  
   Set objFso = CreateObject("Scripting.FileSystemObject")
   If objFso.FileExists(strFile) Then 
      Set objTextStream = objFso.OpenTextFile(strFile, 1)
      Do While Not objTextStream.AtEndOfStream
         strLine = Trim(objTextStream.ReadLine)
         If objFso.FileExists(strLine) Then 
            objFso.DeleteFile strLine, True
         End if
      Loop
      objTextStream.Close
      Set objTextStream = Nothing
   End if
   Set objFso  = Nothing
End function




jean-marc

cs_zatox · Answer

salut, un grand merci à toi, celà fonctionne a merveille, c'est tout à fait ce queje cherchais a faire .

[Déplacé .Net --> VBS] [VBS] supprimer une liste de fichiers.

2 réponses

Votre réponse

Discussions similaires