Bug d'affichage Listview MYSTIQUE !

Question

Bonjour,

J'ai un problème d'affichage VRAIMENT déroutant... 

En fait, les subItems de mes listviews (mode Détail, donc avec les colonnes) ne sont pas affichés quand je change/affecte leurs valeurs... En débogage, je vois que la valeur de la propriété .Text est bien celle que j'attend, mais RIEN n'est affiché (sauf l'item lui-même, donc juste la première colonne).


Par contre, ce bout de code résoud le problème d'affichage (utilisé dans une classe héritant de ListView)

For Each it As ListViewItem In Me.Items
      For Each isub As ListViewItem.ListViewSubItem In it.SubItems
            isub.Text = isub.Text
      Next
Next


Ce code ne sert à RIEN mais pourtant il corrige le problème et permet d'afficher les subItems. Cà m'énerve vraiment parce que :
- je comprend pas pourquoi 
- çà diminue les performances (même si le code ne fait rien, deux For Each imbriqués de 60*10 çà consomme) 


Quelqu'un a une idée 

Merci 
@+

Mayzz · Answer

Salut !

Ce code ne sert à RIEN mais pourtant il corrige le problème

Détrompes-toi, ce code affecte le Set de la propriété Text du subitem, même si le texte est le même Visual Basic ne fait pas la différence, tu remplace simplement le Text par un autre qui a la même valeur. Ce qui à pour impact de déclencher les événements de redraw.

Ce que je ne comprend pas par contre, c'est que le listview ne le fasse pas la première fois. Dans quelles circonstances tu charges ton listview ?

Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Salut !

Oui tout à fait, l'affectation d'une valeur à une propriété appelle systématiquement le code associé dans le setter.
Le code sert donc à rien de manière fonctionnelle, mais bien sur derrière son appel, .Net fait quelques refresh ou autres mises à jour.

Cependant, en théorie il n'est jamais nécessaire de passer par ce genre d'artifice pour forcer la mise à jour des SubItems d'un listview... d'où mon incompéhension de ce qui peut se passer.


Le contexte d'appel est relativement complexe en fait (il s'agit de listviews chargées de mettre à jour des infos en temps réel, exactement comme dans taskmgr par exemple).

Du coup voilà un peu le topo :
- une classe nommée DoubleBufferedLV hérite de ListView et y ajoute la propriété DoubleBuffered, le tri des colonnes, la gestion du reordering des colonnes, la gestion du copier/coller...etc.
- une classe nommée customLV hérite de DoubleBufferedLV, et y ajoute tout un tas de propriétés, des méthodes MustOverride, une gestion d'erreur...etc
- et enfin mes ListViews qui présentent le problème héritent de ce customLV, en forçant la mise à jour du thème de Windows via l'appel à la fonction de l'API Win32 SetWindowTheme, et en utilisant BeginUpdate et EndUpdate avant/après ajout des items.

A noter que les DoubleBufferedLV elles seules n'ont pas le problème.

Ensuite pour l'affichage des items, c'est assez complexe mais voilà le bout de code concerné :


' Now add all new items to listview
        ' If first time, lock listview
        If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE OrElse _dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE Then Me.BeginUpdate()
        For Each z As String In _dicoNew.Keys
            ' Add to listview
            Dim _subItems() As ListViewItem.ListViewSubItem
            ReDim _subItems(Me.Columns.Count - 1)
            For x As Integer = 1 To _subItems.Length - 1
                _subItems(x) = New ListViewItem.ListViewSubItem
            Next
            Dim _tmp As cNetwork = _dico.Item(z)
            AddItemWithStyle(z, _tmp).SubItems.AddRange(_subItems)
        Next
        If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE OrElse _dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE Then Me.EndUpdate()
        _dicoNew.Clear()


        ' Now refresh all subitems of the listview
        Dim isub As ListViewItem.ListViewSubItem
        Dim it As ListViewItem
        For Each it In Me.Items
            Dim x As Integer = 0
            If _dico.ContainsKey(it.Name) Then
                Dim _item As cNetwork = _dico.Item(it.Name)
                If Dico.ContainsKey(it.Name) Then
                    _item.Merge(Dico.Item(it.Name))
                End If
                If _item.ItemHasChanged Then
                    For Each isub In it.SubItems
                        isub.Text = _item.GetInformation(_columnsName(x))
                        x += 1
                    Next
                End If
                If _item.IsNewItem Then
                    _item.IsNewItem = False
                    it.BackColor = NEW_ITEM_COLOR
                ElseIf _item.IsKilledItem Then
                    it.BackColor = DELETED_ITEM_COLOR
                Else
                    it.BackColor = Color.White
                End If
            End If
        Next

        ' This piece of code is needed. Strange behavior, the Text attribute must
        ' be set twice to be properly displayed.
        'If _firstItemUpdate Then
        For Each it In Me.Items
            For Each isub In it.SubItems
                isub.Text = isub.Text
            Next
        Next
        'End If


Bref, j'y perd mon latin et je vois pas quelle particularité de mon code pourrait être la cause de ce problème de rafraichissement...

Si tu as une idée je suis vraiment preneur 

Merci bien 
@+

Mayzz · Answer

Humm... Ca fait pas mal d'héritage la dessus, ya de quoi s'y perdre si t'as pas suivis 

Les customLV elles fonctionnent elle ?

Sinon, tu peut mettre la LV en OwnerDraw et utiliser, le dessin auto, pour voir si cela influ, ca t'aidra peut être à comprendre d'ou vient le bug ?

Genre :


Protected Overrides Sub OnDrawItem(ByVal e As System.Windows.Forms.DrawListViewItemEventArgs)
        MyBase.OnDrawItem(e)
        e.DrawDefault = True
End Sub

Idem pour OnDrawColumnHeader et OnDrawSubitem surtout.

Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Oui j'avoue c'est pas ce qu'il y a de plus simple 

Pour la customLV, elle est n'est pas instanciable en tant que telle (méthodes MustOverride etc), la classe est faite pour être la classe mère d'autres classes.

Sinon pour l'override des classes OnDrawXXX, çà ne change pas le problème. D'ailleurs il n'y a nul part de custom draw en fait, c'est çà qui est embêtant !

Le plus frustrant est que je viens d'essayer d'ajouter manuellement des Items et des subitems dans la ListView :


Dim o As ListViewItem = Me.lvNetwork.Items.Add("dsds")
o.SubItems.Add("4545")


et il n'y a pas de problèmes...

Je suspecte donc le code que j'ai écrit plus haut d'être lui seul à l'origine du problème (pas de problème sur les listviews, mais problème de remplissage de ces listviews).

Le

 .AddRange(_subItems)


 est ce qu'il y a de plus suspect, mais pourtant mon code me semble tout ce qu'il y a de plus correct...

Mayzz · Answer

Effectivement c'est donc bien le contexte.

Et en passant par le Add au lieu du AddRange, avec un Application.DoEvent, cela laissera peut-être le temps au lv de dessiner les élément ?


Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Pour le DoEvents je ne peux pas me permettre de l'utiliser (tout est multithreadé est cette fonction est contre-indiquée).

J'ai essayé d'enlever le AddRange :

        ' Now add all new items to listview
        ' If first time, lock listview
        If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE OrElse _dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE Then Me.BeginUpdate()
        For Each z As String In _dicoNew.Keys
            ' Add to listview
            Dim _tmp As cNetwork = _dico.Item(z)
            Dim i As ListViewItem = AddItemWithStyle(z, _tmp)
            Dim _subItems() As ListViewItem.ListViewSubItem
            ReDim _subItems(Me.Columns.Count - 1)
            For x As Integer = 1 To _subItems.Length - 1
                _subItems(x) = New ListViewItem.ListViewSubItem
                i.SubItems.Add(_subItems(x))
            Next
        Next
        If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE OrElse _dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE Then Me.EndUpdate()
        _dicoNew.Clear()
	

et cela fonctionne, le bug n'apparait plus.... mais le problème de performances est toujours là :(

En effet, remplacer le AddRange par des simples Add est problèmatique quand il s'agit d'ajouter 30 subItems.


Voilà le problème localisé, mais je ne comprend toujours pas en quoi le AddRange (qu'il faut que j'utilise) pose problème ?

Mayzz · Answer

Pour ce qui est de DoEvents ou thread.sleep ou autres c'est claire que ce n'est même pas la peine d'y penser si tu cherche la performance.

Pour repartir depuis le début, tu possede les sources de toutes les classes hérités ?

Les classes SubItem et Items sont-elles celles par défaut de Windows.Form ou ce sont aussi des classes hérités ?

Y-a-t-il un override quelconque sur l'AddRange des subitem quelque part ?

Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Concernant les sources, oui je possède tout puisque c'est moi qui les ai codées.

Donc je peux affirmer que :
- les ListviewItems et ListviewSubItems sont ceux de Windows.Forms
- AddRange n'a jamais overridé dans mon code

J'ai fouillé MSDN mais je n'ai trouvé aucune recommandation particulière quant au AddRange()

cs_Jack · Answer

Salut 
Je n'y connait pas grand chose en .Net, mais ce qui m'épate, c'est ça : 
For Each it In Me.Items
Me désigne en général une forme, en tous les cas, jamais un objet genre ListView. 
Peut-être que les évènements (Redraw) vont sur Me au lieu de la ListView ... 


Vala
Jack, MVP VB
NB : Je ne répondrai pas aux messages privés

Le savoir est la seule matière qui s'accroit quand on la partage (Socrate)

PCPT · Answer

salut,

quelques idées....

1. je suppose que oui mais : point d'arrêt sur tes tests IF, tout OK?
If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_(...)
dans ces cas de test multi-conditions, VB est assez chatouilleux
je m'explique (vb6) :
if len("machin") then => ok 
if len("truc") then => pareil
if len("machin") AND len("truc") then => catastrophe, le AND sera pris comme opérateur logique (normal) mais pas comme on le voudrait dans notre test (on ne fait pas un test BOOL sur le résultat de 6 AND 4)
en remplace par if (len("machin")>0) AND (len("truc")>0) then

çà peut valoir le coup de refaire tes conditions
If (_firstItemUpdate=true) _
OrElse (_dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE) _
OrElse (_dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE) _
Then Me.BeginUpdate()

etc. (autres if)



2. que fais Me.BeginUpdate() ??
(je m'attends à un "lockwinupdate si condition false", voir si l'objet receveur est prêt au moment où tu le souhaites)



3. AddItemWithStyle(z, _tmp).SubItems.AddRange(_subItems)
que fais AddItemWithStyle avant de retourner quoi?

et quelque chose reste confus...
tu utilises addrange, qui va ajouter un tableau de subitems en une fois, c'est bien çà?
parce que là je vois bien l'ajout de ton tableau de subitems, mais sur le résultat d'une fonction...
donc il n'y a pas d'ajout sur la listview, apparemment

c'est une impression bien sûr, et le code que tu montres est trop partiel, mais dans l'idée j'aurais voulu voir :

r  = fonction.SubItems.AddRange(_subItems)
list.items.add r

enfin, dans l'idée...



bon courage

Renfield · Answer

Si si, Jack, quand tu codes un objet ou un usercontrol, Me designe l'instance courante dudit objet...

Renfield - Admin CodeS-SourceS - MVP Visual Basic

violent_ken · Answer

Bonjour !

jack -> Le "Me." désigne l'objet courant (équivalent de this. en C#). En VB6, c'est généralement utilisé pour une form, mais avec le .Net et le "tout objet", "Me." est utilisé pour n'importe quelle classe (cela renvoie l'instance courante de cette classe). En l'occurence ici, cela renvoie à la classe héritée de Listview, donc le .Items est bien celui du listview.


PCPT -> 
1) Oui tout est OK, les opérandes du IF sont toutes des booléennes donc aucun soucis.

2) Me.BeginUpdate/Me.EndUpdate demande effectivement respectivement la désactivation/la réactivation de l'affichage du listview hérité, dans un soucis de performances.
Au moment de l'appel le contrôle est instancié et initialisé, donc à priori pas de problème de ce côté là.

3) En fait "AddItemWithStyle" est une fonction ayant pour but de créer un ListviewItem, et qui renvoie ce dernier. En voici le code :


    ' Add an item (specific to type of list)
    Friend Overrides Function AddItemWithStyle(ByVal key As String) As ListViewItem

        Dim item As ListViewItem = Me.Items.Add(key)
        Dim proc As cProcess = _dico.Item(key)
        item.Name = key

        ' Add to global dico
        cProcess.AssociatePidAndName(key, _dico.Item(key).Infos.Name)

        If _connectionObject.ConnectionType = cConnection.TypeOfConnection.LocalConnection Then
            If proc.Infos.Pid > 4 Then
                ' Add icon
                Try
                    Dim fName As String = proc.Infos.Path

                    If IO.File.Exists(fName) Then
                        Me.SmallImageList.Images.Add(fName, GetIcon(fName, True))
                        item.ImageKey = fName
                    Else
                        item.ImageKey = "noIcon"
                    End If
                Catch ex As Exception
                    item.ImageKey = "noIcon"
                End Try
            Else
                item.ImageKey = "noIcon"
            End If
        Else
            item.ImageKey = "noIcon"
        End If
        item.Tag = key
        Return item
    End Function


Les subItems sont donc ajoutés à l'Item qui vient d'être créé.


Voici le code entier de la classe concernée (même si c'est un peu indigeste )


Option Strict On

Imports System.Runtime.InteropServices

Public Class processList
    Inherits customLV

    Public Event ItemAdded(ByRef item As cProcess)
    Public Event ItemDeleted(ByRef item As cProcess)
    Public Event HasRefreshed()
    Public Event GotAnError(ByVal origin As String, ByVal msg As String)


    ' ========================================
    ' Private
    ' ========================================
    Private _first As Boolean
    Private _enumMethod As asyncCallbackProcEnumerate.ProcessEnumMethode = asyncCallbackProcEnumerate.ProcessEnumMethode.VisibleProcesses
    Private _dicoNew As New Dictionary(Of String, cProcess)
    Private _dicoDel As New Dictionary(Of String, cProcess)
    Private _buffDico As New Dictionary(Of String, cProcess)
    Private _dico As New Dictionary(Of String, cProcess)
    Private WithEvents _connectionObject As New cConnection
    Private WithEvents _processConnection As New cProcessConnection(Me, _connectionObject, New cProcessConnection.HasEnumeratedEventHandler(AddressOf HasEnumeratedEventHandler))

#Region "Properties"

    ' ========================================
    ' Properties
    ' ========================================
    Public Property ConnectionObj() As cConnection
        Get
            Return _connectionObject
        End Get
        Set(ByVal value As cConnection)
            _connectionObject = value
        End Set
    End Property
    Public Property EnumMethod() As asyncCallbackProcEnumerate.ProcessEnumMethode
        Get
            Return _enumMethod
        End Get
        Set(ByVal value As asyncCallbackProcEnumerate.ProcessEnumMethode)
            _enumMethod = value
            _processConnection.EnumMethod = _enumMethod
        End Set
    End Property

#End Region

    ' ========================================
    ' Public functions
    ' ========================================

    Public Sub New()

        ' Cet appel est requis par le Concepteur Windows Form.
        InitializeComponent()

        ' Ajoutez une initialisation quelconque après l'appel InitializeComponent().
        _IMG = New ImageList
        _IMG.ImageSize = New Size(16, 16)
        _IMG.ColorDepth = ColorDepth.Depth32Bit

        Me.SmallImageList = _IMG
        _IMG.Images.Add("noIcon", My.Resources.application_blue)

        _first = True

        ' Set handlers
        _processConnection.Disconnected = New cProcessConnection.DisconnectedEventHandler(AddressOf HasDisconnected)
        _processConnection.Connected = New cProcessConnection.ConnectedEventHandler(AddressOf HasConnected)
    End Sub

    ' Get an item from listview
    Public Function GetImageFromImageList(ByVal key As String) As System.Drawing.Image
        Return _IMG.Images.Item(key)
    End Function

    ' Delete all items
    Public Sub ClearItems()
        _first = True
        _firstItemUpdate = True
        _buffDico.Clear()
        _dico.Clear()
        _dicoDel.Clear()
        _dicoNew.Clear()
        _IMG.Images.Clear()
        _IMG.Images.Add("noIcon", My.Resources.application_blue)
        Me.Items.Clear()
    End Sub

    ' Reanalize a process
    Public Sub ReAnalizeProcesses()
        Dim pid() As Integer
        ReDim pid(Me.GetSelectedItems.Count - 1)
        Dim x As Integer = 0
        For Each cp As cProcess In Me.GetSelectedItems
            pid(x) = cp.Infos.Pid
            x += 1
        Next
        asyncCallbackProcEnumerate.ReanalizeProcess(New asyncCallbackProcEnumerate.ReanalizeProcessObj(pid, _processConnection))
    End Sub

    ' Call this to update items in listview
    Public Overrides Sub UpdateItems()

        ' Create a buffer of subitems if necessary
        If _columnsName Is Nothing Then
            Call CreateSubItemsBuffer()
        End If

        If _processConnection.IsConnected Then

            ' Now enumerate items
            _processConnection.Enumerate(_first, enumMethod:=_enumMethod)

        End If

    End Sub

    ' Get all items (associated to listviewitems)
    Public Function GetAllItems() As Dictionary(Of String, cProcess).ValueCollection
        Return _dico.Values
    End Function

    ' Get the selected item
    Public Function GetSelectedItem() As cProcess
        If Me.SelectedItems.Count > 0 Then
            Return _dico.Item(Me.SelectedItems.Item(0).Name)
        Else
            Return Nothing
        End If
    End Function

    ' Get a specified item
    Public Function GetItemByKey(ByVal key As String) As cProcess
        If _dico.ContainsKey(key) Then
            Return _dico.Item(key)
        Else
            Return Nothing
        End If
    End Function

    ' Get selected items
    Public Shadows Function GetSelectedItems() As Dictionary(Of String, cProcess).ValueCollection
        Dim res As New Dictionary(Of String, cProcess)

        For Each it As ListViewItem In Me.SelectedItems
            res.Add(it.Name, _dico.Item(it.Name))
        Next

        Return res.Values
    End Function


    ' ========================================
    ' Private properties
    ' ========================================

    ' Executed when enumeration is done
    Private Shared sem As New System.Threading.Semaphore(1, 1)
    Private Sub HasEnumeratedEventHandler(ByVal Success As Boolean, ByVal Dico As Dictionary(Of String, processInfos), ByVal errorMessage As String, ByVal instanceId As Integer)

        sem.WaitOne()

        If Success = False Then
            Trace.WriteLine("Cannot enumerate, an error was raised...")
            RaiseEvent GotAnError("Process enumeration", errorMessage)
            sem.Release()
            Exit Sub
        End If

        ' We won't enumerate next time with all informations (included fixed infos)
        _first = False


        ' Now add all items with isKilled = true to _dicoDel dictionnary
        For Each z As cProcess In _dico.Values
            If z.IsKilledItem Then
                _dicoDel.Add(z.Infos.Pid.ToString, Nothing)
            End If
        Next


        ' Now add new items to dictionnary
        For Each pair As System.Collections.Generic.KeyValuePair(Of String, processInfos) In Dico
            If Not (_dico.ContainsKey(pair.Key)) Then
                ' Add to dico
                _dicoNew.Add(pair.Key, New cProcess(pair.Value))
            End If

        Next


        ' Now remove deleted items from dictionnary
        For Each z As String In _dico.Keys
            If Dico.ContainsKey(z) = False Then
                ' Remove from dico
                _dico.Item(z).IsKilledItem = True  ' Will be deleted next time
            End If
        Next


        ' Now remove all deleted items from listview and _dico
        For Each z As String In _dicoDel.Keys
            Me.Items.RemoveByKey(z)
            RaiseEvent ItemDeleted(_dico.Item(z))
            _dico.Remove(z)
            cProcess.UnAssociatePidAndName(z)    ' Remove from global dico
        Next
        _dicoDel.Clear()


        ' Merge _dico and _dicoNew
        For Each z As String In _dicoNew.Keys
            Dim _it As cProcess = _dicoNew.Item(z)
            RaiseEvent ItemAdded(_it)
            _it.IsNewItem = Not (_firstItemUpdate)        ' If first refresh, don't highlight item
            _dico.Add(z.ToString, _it)
        Next


        cProcess.SemCurrentProcesses.WaitOne()
        cProcess.CurrentProcesses = New Dictionary(Of String, cProcess)((_dico))
        cProcess.SemCurrentProcesses.Release()


        ' Now add all new items to listview
        ' If first time, lock listview
        If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE OrElse _dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE Then Me.BeginUpdate()
        For Each z As String In _dicoNew.Keys

            ' Add to listview
            Dim _subItems() As ListViewItem.ListViewSubItem
            ReDim _subItems(Me.Columns.Count - 1)
            For x As Integer = 1 To _subItems.Length - 1
                _subItems(x) = New ListViewItem.ListViewSubItem
            Next
            AddItemWithStyle(z).SubItems.AddRange(_subItems)
        Next
        If _firstItemUpdate OrElse _dicoNew.Count > EMPIRIC_MINIMAL_NUMBER_OF_NEW_ITEMS_TO_BEGIN_UPDATE OrElse _dicoDel.Count > EMPIRIC_MINIMAL_NUMBER_OF_DELETED_ITEMS_TO_BEGIN_UPDATE Then Me.EndUpdate()
        _dicoNew.Clear()


        ' Now refresh all subitems of the listview
        Dim isub As ListViewItem.ListViewSubItem
        Dim it As ListViewItem
        For Each it In Me.Items
            Dim x As Integer = 0
            Dim _item As cProcess = _dico.Item(it.Name)
            If Dico.ContainsKey(it.Name) Then
                _item.Merge(Dico.Item(it.Name))
            End If
            If _item.ItemHasChanged Then
                For Each isub In it.SubItems
                    isub.Text = _item.GetInformation(_columnsName(x))
                    x += 1
                Next
            End If
            If _item.IsNewItem Then
                _item.IsNewItem = False
                it.BackColor = NEW_ITEM_COLOR
            ElseIf _item.IsKilledItem Then
                it.BackColor = DELETED_ITEM_COLOR
            Else
                it.BackColor = _item.GetBackColor
            End If
            it.ForeColor = _item.GetForeColor

            ' If we are in 'show hidden process mode', we have to set color red for
            ' hidden processes
            If _item.Infos.IsHidden Then
                it.ForeColor = Color.Red
            Else
                If it.ForeColor = Color.Red Then
                    it.ForeColor = Color.Black
                End If
            End If
        Next

        ' This piece of code is needed. Strange behavior, the Text attribute must
        ' be set twice to be properly displayed.

        ' /!\ Le problème est ICI
        ' Ce code ne devrait pas exister
        'If _firstItemUpdate Then
            For Each it In Me.Items
                For Each isub In it.SubItems
                    isub.Text = isub.Text
                Next
            Next
        'End If
        ' /!\ Le problème est ICI

        ' Set processes to task class
        cTask.ProcessCollection = _dico


        ' Sort items
        Me.Sort()

        _firstItemUpdate = False

        'Trace.WriteLine("It tooks " & _test.ToString & " ms to refresh process list.")

        MyBase.UpdateItems()

        sem.Release()
    End Sub


    ' Add an item (specific to type of list)
    Friend Overrides Function AddItemWithStyle(ByVal key As String) As ListViewItem

        Dim item As ListViewItem = Me.Items.Add(key)
        Dim proc As cProcess = _dico.Item(key)
        item.Name = key

        ' Add to global dico
        cProcess.AssociatePidAndName(key, _dico.Item(key).Infos.Name)

        If _connectionObject.ConnectionType = cConnection.TypeOfConnection.LocalConnection Then
            If proc.Infos.Pid > 4 Then

                ' Add icon
                Try

                    Dim fName As String = proc.Infos.Path

                    If IO.File.Exists(fName) Then
                        Me.SmallImageList.Images.Add(fName, GetIcon(fName, True))
                        item.ImageKey = fName
                    Else
                        item.ImageKey = "noIcon"
                    End If

                Catch ex As Exception
                    item.ImageKey = "noIcon"
                End Try

            Else
                item.ImageKey = "noIcon"
            End If
        Else
            item.ImageKey = "noIcon"
        End If

        item.Tag = key

        Return item

    End Function

#Region "Connection stuffs"

    Private Sub _connectionObject_Connected() Handles _connectionObject.Connected
        Call Connect()
    End Sub

    Private Sub _connectionObject_Disconnected() Handles _connectionObject.Disconnected
        Call Disconnect()
    End Sub

    Private Sub Connect()
        _first = True
        _processConnection.ConnectionObj = _connectionObject
        asyncCallbackProcEnumerate.ClearDico()
        _processConnection.Connect()
        cProcess.Connection = _processConnection
    End Sub

    Private Sub Disconnect()
        _processConnection.Disconnect()
        asyncCallbackProcEnumerate.ClearDico()
    End Sub

    Private Sub HasDisconnected(ByVal Success As Boolean)
        ' We HAVE TO disconnect, because this event is raised when we got an error
        '_processConnection.Disconnect()
        '     _processConnection.Con()
    End Sub

    Private Sub HasConnected(ByVal Success As Boolean)
        '
    End Sub

#End Region

    Protected Overrides Sub OnKeyDown(ByVal e As System.Windows.Forms.KeyEventArgs)
        MyBase.OnKeyDown(e)
        If e.Shift AndAlso e.Control Then
            ' OK, show thread management
            For Each obj As cGeneralObject In Me.GetSelectedItems
                Dim frm As New frmPendingTasks(obj)
                frm.Show()
            Next
        End If
    End Sub
End Class



Merci pour votre aide et vos idées ! 
@+

violent_ken · Answer

Re bonsoir,

j'ai réussi à isoler le problème.
Voici comment le reproduire (ajoutez une listview nommée ListView1 dans une form et lancez ce code) :


        ' On ajoute 50 ListViewItems
        For i As Integer = 1 To 50

            ' Creation des subitems
            Dim subs() As ListViewItem.ListViewSubItem
            ReDim subs(Me.ListView1.Columns.Count - 1)

            ' Instanciation des subitems
            For x As Integer = 1 To subs.Length - 1
                subs(x) = New ListViewItem.ListViewSubItem
            Next

            ' Creation d'un item
            Dim unItem As ListViewItem = New ListViewItem
            Me.ListView1.Items.Add(unItem)

            ' Ajout des subitems
            unItem.SubItems.AddRange(subs)
        Next

        ' On affecte le texte on subitems
        For Each it As ListViewItem In Me.ListView1.Items
            For Each subit As ListViewItem.ListViewSubItem In it.SubItems
                subit.Text = "TEST"
            Next
        Next

        ' Voilà le bug...
        For Each it As ListViewItem In Me.ListView1.Items
            For Each subit As ListViewItem.ListViewSubItem In it.SubItems
                ' Enlever cette ligne pour tester
                subit.Text = subit.Text
            Next
        Next



Le code est très simple, et j'ai beau le relire je ne vois pas où çà coince 
Je suis sur que çà doit être évident puisque le code semble trivial, mais je ne vois pas... 

Vous auriez une idée ?

Merci bien !
@+

violent_ken · Answer

J'ai trouvé d'où çà vient : c'est le constructeur des SubItems qui n'est pas satisfaisant.

Si je créé en premier le ListViewItem et que je passe dans le constructeur des SubItems ce ListViewItem en tant qu'owner, çà fonctionne.

Bref, le AddRange n'est pas capable de faire la relation : les SubItems appartenant aux Items ne sont pas renseignés comme leur appartenant. Si je les ajoute un par un, pas de problème.

Alors si j'ai localisé le problème, je ne le comprend pas :
- pourquoi le lien de parenté est-il raté quand je fais AddRange ?
- pourquoi il n'y a aucune recommandation sur MSDN quant à l'utilisation de ce AddRange ?
- pourquoi l'appel au Setter de la propriété .Text réalise l'affichage ?
- pourquoi le lien de parenté, même s'il est raté, existe bien puisque l'accès aux Items et leurs SubItems est tout à fait possible (via le code, ou en débogage) ?


Bref, j'aimerais bien comprendre... Si vous avez une idée je suis preneur !
Merci,
@+

Mayzz · Answer

Je viens de voir un post tout à l'heure concernant reflector, c'est peut être bête mais si l'on peut désassembler le framework (pas fiable à 100%) alors pourquoi pas regarder ce que contient AddRange ?


Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Bonne idée, je regarderais ce qui se cache derrière le AddRange.

J'ai fait quelques benchmarks, et sur ma machine, pour ajouter 20000 items avec chacun 10 subitems :
- 3681 ms avec le bug (AddRange d'un tableau de listview dont le constructeur est le constructeur par défaut)
- 14900 ms avec AddRange d'un tableau de String non nulles (le bug n'est pas présent)
- 14950 ms avec AddRange d'un tableau de listviewsubitems instanciés avec comme Owner le listviewitem (le bug n'est pas présent)

Clairement l'implémentation est différente, et si l'owner des subitems n'est pas spécifié, ce n'est pas fait automatiquement par le AddRange.


Je ne pense pas que je soit tombé sur un bug du framework, des tas de gens l'utilisent et AddRange est plutôt commun, et j'ai vu nul part de problème semblable.
Par contre clairement il y a un manque de documentation sur cette méthode, aucun avertissement sur son utilisation (si ce n'est pas un bug) !

@+

Mayzz · Answer

Il me semble que j'ai eu un bug avec les subitems dans une source que j'ai déposé ici, ceux-ci ne se dessine pas en mode 'Détails'...

Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Re bonjour,

je traine toujours mon problème derrière moi...

J'ai bien trouvé une correction (en changeant le constructeur des SubItems), mais j'ai fait un bench et voilà le résultat :

L'ajout des subitems, quand il est bugué, prend 3 fois moins de temps que l'ajout non bugué (et les subite.text = subit.text sont compris dans le temps) !!


Bref, le bug permet une optimisation assez impressionnante des performances d'ajout, mais çà m'embête quand même de trainer le bout de code subite.text = subit.text ....

Le mieux serait de pouvoir se passer de morceau de code (qui prend quand même beaucoup de temps CPU, même si le total ajout+refresh est 3 fois plus rapide) sans pour autant perdre le bénéfice des performances...

Quelqu'un a une idée pour ajouter/rafraichir le plus rapidement possible tous les subitems de tous les items d'un listview ?


Mayzz -> quelle est le nom de ta source ?

Merci
@+

Mayzz · Answer

Heu... Une idée oui, mais qui prend du temps, j'expose :

Tu peux créer ta propre collection d'items et de subitems en overload sur un listview, et redessiner toi même ceux-ci via ownerdraw et ses méthodes... Le problème à étudier est ce fameux bug :

Voici ma source, pour voir le bug, lance la, puis met le view sur Details, ajoute des éléments et passe le curseur sur les subitems, ceux-ci disparaissent et ne se redessinent pas. 

J'ai fais un pas à pas et ce qui ce passe c'est que la méthode DrawSubitem est appelé (une seule foi seulement) mais seul le premier élément est passé en parametre du System.Windows.Forms.DrawListViewSubItemEventArgs, c'est à dire le texte de l'item. J'ai d'abbord cru à une erreur de développement de ma part, mais il n'en est rien, c'est bien un bug du listview. 

As-t-il un rapport avec ton bug ? Je ne saurais te le dire, mais si c'est le cas cela peu peut être te faire avancer ? 

Bon courrage dans tous les cas...


Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Je viens de regarder ta source (pas mal du tout au passage), et effectivement c'est bien un problème du ListView.

Pour mon problème, bonne idée, je vais essayer de faire un OwnerDraw, peut-être trouverais-je des pistes ?

Bon ben je pense qu'il faut en conclure que le ListView est bugué 

Assez étonnant mais c'est bien le cas apparemment...

Merci en tout cas pour l'aide 
@+

Mayzz · Answer

Bah, tu parles...

Pour l'ownerdraw, regarde l'exemple MSDN

@+

Si le déboguage est l'art d'enlever les bogues, la programmation doit être l'art de les créer.

violent_ken · Answer

Ben le listview de .Net est pas récent quand même ?! Etonnant que personne n'ait remarqué ce genre de problèmes, et qu'il ne soit pas corrigé depuis le temps ?

@+

PerryCicle · Answer

J'ai eu un peu le même problème sur un de mes ListView, j'étais en mode ownerdraw et la première colonne apparaissait, la deuxième aussi mais lorsque je passais ma souris par dessus les cases de la deuxième colonne disparaissait.

La seule solution que j'ai trouvé est de simulé le clique sur tout les items ( première colonne ) ce qui me faisait apparaitre toutes les deuxièmes colonnes de manière persistante.

Ensuite appeler la méthode à l'évènement shown ( j'ai passé près de Trois jours sur ça mdr )

Bug d'affichage Listview MYSTIQUE !

23 réponses

Votre réponse

Discussions similaires