Récupération titre page excelRésolu

Question

Bonjour,

Je suis débutant en VBA et je cherche à récupérer la valeur de l'onglet tout en bas de la page excel.

Je sais pas si je suis assez clair.

Merci a ceux qui pourront m'aider

Cordialement

Renfield · Accepted Answer

ActiveSheet.Name ?

justin92330 · Answer

Oui c'est exactement ca ! désolé de ma nulité lol

Est ce que je peux abuser et te demander si tu sais comment je pourrai faire pour lister un repertoire et récupérer tous les ActivesSheet.Name dans un tableau
( Si possible sans ouvrir les pages )

Merci encore

Renfield · Answer

tu devras forcément ouvrir les fichiers Excel pour en lister les feuilles.
pas obligé, par contre que ca soit visible

voir la collection WorkSheets d'un classeur WorkBook
passer par Workbooks pour ouvrir tes fichiers listés avec Dir$

justin92330 · Answer

J'ai cherché a quoi correspondait le Workbook et le Worksheets mais je ne vois pas en quoi ca peut me servir.  

Ne serait-il pas plus simple d'ouvrir toutes les pages excel dans un meme classeur pour pouvoir traiter les informations plus simplement?

Excuse moi de t'ennuyer autant

Renfield · Answer

Sub
test()
Dim xsSheetNames() As String
Dim nSheetNames As Long
Dim sFileName As String
Dim sFolder As String
Dim oSheet As Worksheet
   '# Mets ici le repertoire a scanner
   sFolder = "D:\Documents and Settings\THOM31R\Mes documents\Fiches de temps\"
   '# On va lister les fichiers XLS
   sFileName = Dir$(sFolder & "*.xls")
   Do While LenB(sFileName)
       '# On ouvre les fichiers un a un
       With Application.Workbooks.Add(sFolder & sFileName)
           '# Pour enumérer leur feuilels
           For Each oSheet In .Worksheets
               '# Et les ajouter dans notre tableau dynamique
               ReDim Preserve xsSheetNames(nSheetNames)
               xsSheetNames(nSheetNames) = oSheet.Name
               nSheetNames = nSheetNames + 1
           Next oSheet
           '# Fermeture du fichier Excel
           .Close
       End With
       '# On demande le fichier suivant
       sFileName = Dir$()
   Loop
   
   '# Ici, on affiche simplement le contenu de notre tableau
   Dim i As Long
   For i = 0 To nSheetNames - 1
       MsgBox xsSheetNames(i)
   Next i
End Sub ,

----

By Renfield








Renfield





Admin CodeS-SourceS

- MVP Visual Basic

justin92330 · Answer

Merci c'est génial je comprends mieux leurs utilisation maintenant 

Merci pour tout

Best Regard

Récupération titre page excel

6 réponses

Votre réponse