Détecter le composant mail du serveur

Télécharger le projet
Commenter

Description

Ce code QUI N'EST PAS DE MOI, permet de détecter les composant mail présent sur le serveur où votre site est hébergé.

Pratique quand l'on n'a pas ces informations (justes les logins FTP ;) et pas le temps forcément de demander à l'administrateur ce genre d'info (surtiout si celui-ci prend 3 semaines pour répondre).

Il est facilement modifiable pour rajouter d'autres composants mail ou autres. D'ailleurs, si vous avez les infos d'autres composants, je serais ravi de les rajouter et de les envoyer à l'auteur original.
Les modifications des composants sont de la ligne 14 à 16.

Source / Exemple : 


<%@Language="VBScript"%>
<head>
	<title>Email components</title>
	<style>
		body {font: 12px arial; border: 0px jingle; background: white}
	</style>
</head>
<b>The checked boxes are the installed components:</b>
<%
	'Response.Buffer = True
	Server.ScriptTimeout = 60
	lastUpdate = "24/04/2002"

	Dim nbObject : nbObject = 6
	Dim ProgID : ProgID = array("SMTPsvg.Mailer", "SMTPsvg.Mailer", "Persits.MailSender", "CDONTS.NewMail", "Jmail.smtpmail", "SoftArtisans.SMTPMail")
	Dim Label  : Label = array("ASPMail", "ASPQMail", "ASPEmail", "CDOMail", "JMail", "SASmtpMail")
	
	Sub AutoDetect()
		Dim i
		
		For i=0 to nbObject-1
			if IsObjInstalled(ProgID(i)) then
				Response.Write "<script>window.opener.frmFullxml.emailCOM.value='" & Label(i) & "';self.close()</script>"
			end if
		Next
	End Sub 
	
	Sub Sniffer()
		Dim i
		
		For i=0 to nbObject-1
			if IsObjInstalled(ProgID(i)) then
				Response.Write "<input type=checkbox checked disabled>&nbsp;<font color=green>" &Label(i) & "</font><br>"
				'exit sub
			else
				Response.Write "<input type=checkbox disabled>&nbsp;<font color=red>"& Label(i) & "</font><br>" 
			end if
		Next
	End Sub 

	Function IsObjInstalled(strClassString)
		On Error Resume Next
		IsObjInstalled = False
		Err = 0
		Dim xTestObj
		Set xTestObj = Server.CreateObject(strClassString)
		If 0 = Err Then IsObjInstalled = True
		Set xTestObj = Nothing
		Err = 0
	End Function
	
	'----------
	if lenb(request("o"))=0 then 
		Sniffer()
	else
		AutoDetect()
	end if
%>

Conclusion :


Ce script vient directement (sans AUCUNE modification) de Full-XML (http://www.fullxml.com). Fichier /help/email_sniffer.asp.
Télécharger le projet

Codes Sources

A voir également

S'inscrire maintenant

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.