WautoIdentifyGhost V1.0 est un addon auto identificateur de pseudo et auto ghost killer multi serveur.
Au début vous trouverez dans le menu bar WautoIdentifyGhost V1.0, vous trouverez « configurer » pour ajouter des ID et « désinstaller » pour détaller l?addon de votre script.
Dans la configuration vous trouverez les détails sur la capture juste a coté.
Vous avez des cases à remplir et les données seront classées comme ça :
<nick>.<pass>.<network>.<command identify>.<command ghost>
Une fois que vous enregistrez un pseudo, une fenêtre s?ouvre pour crée un pseudo de secours et la deuxième fois la même fenêtre s?ouvre de nouveau en vous informant le Nick de secours actuel que vous avez eus a crée bien avant, au cas que vous désirez le modifier
Ce pseudo vous sera utile, en cas que votre pseudo est déjà sur le serveur, pour que la commande Ghost s'exécute automatiquement, et une fois votre pseudo est kill, le pseudo de secours redevient le pseudo que vous vous étiez connecté avec.
Par exp: si tu étais connecté avec X le pseudo devient R (pseudo de secours) et il kill ton pseudo (X) a fin de redevenir X de nouveau
Veuillez mettre un pseudo que vous utilisez pas pour personne peut avoir (aléatoire) par exp: ioijoijo, qgfdgf ou autres
Si vous ne mettez pas de pseudo, lors d?un Ghost, le pseudo de secours sera par défaut WorldDMT_Ghost
Et au cas que vous êtes connecté et que vous changez de pseudo si le nouveau pseudo est en cours d?utilisation et aussi dans la liste des pseudo enregistrer il exécute la commande ghost el il change de l?ancien au nouveau nick.
Au cas que vous ajoutez deux fois les mêmes données une fenêtre s?ouvre pour vous avertir et vous trouverez une fenêtre qui affiche, les détails, plus clair en grande liste.
Un conseil si vous vous connectez en clones souvent, rassurez vous de faire plusieurs fichier de script ne vous connectez pas d'un même script, si non un de vos clone sera ghost kill, donc par exp: si vous avez 2 ou 3 clones faites 3 dossier et chaque dossier contiens le WautoIdentifyGhost a part pour ne pas avoir les mêmes nicks dans un même addon mais si vous veillez a que chaque dossier a son ID différent vous n'aurez pas un problème.
Les défauts de cet addon qu?il fonctionne sur les serveurs qui les commandes :
<command identify> <pass>
<command ghost> <nick> <pass>
Dalnet par exp: /identify <pass>
/ns ghost <nick> <pass>
Source / Exemple :
menu menubar {
-
WautoIdentifyGhost V1.0
.Configurer:wig
.Désinstaller:dwig
}
alias wig {
if ($dialog(AutoID)) return
else dialog -rm AutoID AutoID
}
alias dwig {
if ($dialog(deswig)) return
else dialog -ma deswig deswig
}
alias stat.off { echo -a ** WautoIdentifyGhost Status 14[ 4OFF 14] }
alias pas.inclu1 { echo -a ** le pseudo 14[4 %newnick 14]2 est en cours d'utilisation, et il n'est pas dans la liste de auto ID veuillez l'ajouté pour pouvoir le récupérer automatiquement la prochaine fois }
alias pas.inclu2 { echo -a ** le pseudo 14[4 %ghostnick 14]2 est en cours d'utilisation, et il n'est pas dans la liste de auto ID veuillez l'ajouté pour pouvoir le récupérer automatiquement la prochaine fois }
alias verify.open { if ($dialog(psecours)) return | did -b AutoID 2,5,6,21,22,23,24,25,26,28,29,31,32,17,18,19 | did -h AutoID 27,30,33 | $1- }
alias verify.open1 { did -e AutoID 2,5,6,21,22,23,24,25,26,28,29,31,32,17,18,19 | did -v AutoID 27,30,33 }
alias verify.open2 { if (($dialog(aide1)) || ($dialog(aide2)) || ($dialog(aide3)) || ($dialog(aide4)) || ($dialog(aide5))) return | $1- }
dialog AutoID {
title WorldDMT Auto Identify & Ghost V1.0
size -1 -1 166 122
option dbu
text ~~~~~~~~~~~~~~~~~~~~~~~~~ le $date ~~~~~, 1, 1 112 165 8, center disable
check Status OFF, 2, 5 111 36 9
text Vous etes sur le network $network , 3, 8 31 90 8, left disable
text ~~ © 2008 ~~, 4, 6 16 40 8, left disable
box Nick Auto Identifier, 5, 110 24 54 87
list 6, 112 32 50 77, sort size extsel hsbar
box Ajouter ID, 20, 2 24 106 65
text Nickname, 21, 7 38 40 8, left
edit , 22, 40 38 60 9, autohs
text Password, 23, 7 48 40 8, left
edit , 24, 40 48 60 9, autohs
text Network, 25, 7 58 40 8, left
edit , 26, 40 58 60 9, autohs
link ?, 27, 102 58 5 8
text Com.identify, 28, 7 68 40 8, left
edit , 29, 40 68 60 9, autohs
link ?, 30, 102 68 5 8
text Com.Ghost, 31, 7 78 40 8, left
edit , 32, 40 78 60 9, autohs
link ?, 33, 102 78 5 8
box , 15, 2 86 106 25
button Suprimer select., 17, 55 91 52 9
button Ajouter, 18, 3 91 52 9,
button Fermer, 19, 3 100 104 9, ok
text ~V1.0~, 16, 143 13 20 7, center disable
text WorldDMT Script, 34, 6 6 40 8, left disable
box , 35, 2 1 50 15
text WorldDMT Auto Identify et Ghost, 36, 55 13 82 8, left disable
box , 37, 47 8 95 15
text ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~, 38, 56 3 100 7, left disable
box , 39, 53 1 105 8
}
dialog deswig {
title "Désinstaller WautoIdentify & Ghost"
size -1 -1 150 40
option dbu
box "ATTENTION!!", 64, 1 2 148 37
text "Cette action supprime l?addon WautoIdentifyGhost V1.0 voulez-vous désinstallé WautoIdentifyGhost ?", 65, 12 9 125 24, Center
button "Oui", 66, 45 25 30 12, ok
button "Non", 67, 75 25 30 12, cancel
}
dialog aide1 {
title WorldDMT Auto identify Aide
size -1 -1 130 45
option dbu
box Aide Network, 40, 2 3 125 38
text "Dans cette case, vous mettez le network que vous vous connectez. Par exp: si le serveur que vous vous etes connecté est irc.dal.net vou mettez ''DALnet''", 41, 5 10 118 32, left
}
dialog aide2 {
title WorldDMT Auto identify Aide
size -1 -1 130 45
option dbu
box Aide Identify Command, 42, 2 3 125 38
text "Dans cette case, vous mettez la commende que vous utilisez pour identifier votre pseudo selon votre network si vous etes sur Dalnet par exp: /msg NickServ@services.dal.net IDENTIFY", 43, 5 10 118 32, left
}
dialog aide3 {
title WorldDMT Auto identify Aide
size -1 -1 130 45
option dbu
box Aide Ghost Command, 44, 2 3 125 38
text "Dans cette case, vous mettez la commende que vous utilisez pour recupérer votre pseudo en ghost command si vous etes sur Dalnet par exp: /msg NickServ@services.dal.net GHOST", 45, 5 10 118 32, left
}
dialog aide4 {
title WorldDMT Pseudo de secours Aide
size -1 -1 170 100
option dbu
box Aide Pseudo de secours, 53, 2 3 166 96
text "Ce pseudo vous sera utile, en cas que votre pseudo est déjà sur le serveur, pour que la commande Ghost s'exécute automatiquement, et une fois votre pseudo est kill, le pseudo de secours redevient le pseudo que vous vous étiez connecté avec.", 54, 6 10 160 32, left
text "Par exp: si tu étais connecté avec X le pseudo devient R (pseudo de secours) et il kill ton pseudo (X) a fin de redevenir X de nouveau. ", 55, 6 42 160 24, left
text "Veuillez mettre un pseudo que vous utilisez pas pour personne peut avoir (aléatoire) par exp: ioijoijo, qgfdgf ou autres", 56, 6 65 160 24, left
text "Si vous ne mettez pas de pseudo, lors d?un Ghost, le pseudo de secours sera par défaut WorldDMT_Ghost", 57, 6 82 160 24, left
}
dialog aide5 {
title WorldDMT liste complete de Pseudo Aide
size -1 -1 170 100
option dbu
box Liste de Pseudo, 61, 2 3 166 96
text Les pseudos sont classer dans un fichier sous le model <nick>.<pass>.<network>.<com.identify>.<com.ghost>, 62, 6 10 160 18, left
list 63, 5 27 160 70, sort size
}
dialog erreur {
title WorldDMT Auto identify Note
size -1 -1 130 45
option dbu
box Attention!!, 58, 2 3 125 38
text Ces données sont dejà enregistrées, 59, 5 12 118 8, center
link Cliquez ici pour voir la liste complete, 60, 22 22 86 8
}
dialog psecours {
title W Auto ID Pseudo de secours
size -1 -1 130 60
option dbu
box Pseudo de secours, 46, 2 3 125 55
text Votre pseudo de secours actuel est, 47, 3 29 124 8, center
edit %nick.secours, 48, 20 37 90 9, center autohs
button OK, 49, 50 47 30 10, ok
button , 50, 50 47 30 10, hide
text Pour savoir utilité d'avoir un pseudo de secours, 51, 8 12 115 8, left
link Cliquez ici, 52, 50 20 30 8
}
on *:dialog:deswig:sclick:66: unload -rs AutoID/AutoID.txt
on *:dialog:psecours:close:*: verify.open1
on *:dialog:psecours:*:*: {
if (!%nick.secours) {
did -h $dname 49
did -ra $dname 47 Veuillez entrer un pseudo de secours Ghost
}
if ($devent == edit) {
if ($did(48).edited) { did -rav $dname 50 crée }
}
if ($devent == sclick) {
if ($did == 52) { verify.open2 dialog -oam aide4 aide4 }
if ($did == 50) {
if (!$did(48)) { did -ra $dname 47 Veuillez entrer un pseudo | return }
if ($chr(32) isin $did(48)) { did -ra $dname 47 Veuillez entrer un pseudo sans espaces | return }
set %nick.secours $did(48)
did -h $dname 50
did -v $dname 49
}
}
if (%nick.secours) {
if ($devent == sclick) {
if ($did == 50) {
if (!$did(48)) { did -ra $dname 47 Veuillez entrer un pseudo | return }
if ($chr(32) isin $did(48)) { did -ra $dname 47 Veuillez entrer un pseudo sans espaces | return }
set %nick.secours $did(48)
did -h $dname 50
did -ra $dname 47 Votre pseudo de secours a été ajouté
}
}
if ($devent == edit) {
if ($did(48).edited) { did -rav $dname 50 changer | did -h $dname 49 }
if ($did(48) == %nick.secours) { did -h $dname 50 | did -v $dname 49 }
}
}
}
on *:dialog:erreur:close:*: verify.open1
on *:dialog:erreur:*:*: {
if ($devent == sclick) {
if ($did == 60) { verify.open2 dialog -oam aide5 aide5 }
}
}
on *:dialog:aide5:*:*: {
if ($devent == init) {
loadbuf -o aide5 63 AutoID/nickname.txt
}
}
on *:dialog:aide1:close:*: verify.open1
on *:dialog:aide2:close:*: verify.open1
on *:dialog:aide3:close:*: verify.open1
on *:dialog:AutoID:sclick:27: verify.open dialog -oam aide1 aide1
on *:dialog:AutoID:sclick:30: verify.open dialog -oam aide2 aide2
on *:dialog:AutoID:sclick:33: verify.open dialog -oam aide3 aide3
on *:dialog:AutoID:*:*: {
if ($devent == sclick) {
if ($did(2).state) set %waid 1 | else unset %waid
if (%waid) did -ra $dname 2 Status ON | else did -ra $dname 2 Status OFF
}
if ($devent == init) {
loadbuf -o AutoID 6 AutoID/nickname.txt
if (%waid) { did -c $dname 2 | did -ra $dname 2 Status ON }
}
if ($did == 18) {
if (!$did(22)) { did -ra $dname 20 * veuillez entrer un pseudo | timer1 1 3 if ($dialog(AutoID)) did -ra $dname 20 Ajouter ID | return }
if (!$did(24)) { did -ra $dname 20 * veuillez entrer un mot de passe | timer2 1 3 if ($dialog(AutoID)) did -ra $dname 20 Ajouter ID | return }
if (!$did(26)) { did -ra $dname 20 * veuillez entrer le network | timer3 1 3 if ($dialog(AutoID)) did -ra $dname 20 Ajouter ID | return }
if (!$did(29)) { did -ra $dname 20 * veuillez entrer la commande d'identify | timer4 1 3 if ($dialog(AutoID)) did -ra $dname 20 Ajouter ID | return }
if (!$did(32)) { did -ra $dname 20 * veuillez entrer la commande Ghost | timer5 1 3 if ($dialog(AutoID)) did -ra $dname 20 Ajouter ID | return }
var %nick = $did(22) $+ $chr(46) $+ $did(24) $+ $chr(46) $+ $did(26) $+ $chr(46) $+ $did(29) $+ $chr(46) $+ $did(32)
var %l = $lines(AutoID/nickname.txt)
var %l > 0
var %i = 0
while %i < %l {
inc %i
if (%nick == $gettok($read(AutoID/nickname.txt,%i),1-,46)) {
verify.open dialog -oam erreur erreur
return
}
did -a $dname 6 %nick
did -r $dname 22,24,26,29,32
did -ra $dname 20 * $chr(32) Pseudo ajouté | timer6 1 1 if ($dialog(AutoID)) { did -ra $dname 20 Ajouter ID }
savebuf -o $dname 6 AutoID/nickname.txt
timer7 1 1 { verify.open dialog -oam psecours psecours }
return
}
}
if ($did == 17) && ($did(6,0).sel > 0) {
var %i = 1
while $did(6,%i).sel {
did -d AutoID 6 $did(6,%i).sel
}
inc %i
savebuf -o AutoID 6 AutoID/nickname.txt
}
}
on *:nick:{
if ($nick == $me) {
if (%waid) {
var %l = $lines(AutoID/nickname.txt)
var %i = 0
while %i < %l {
inc %i
if ($newnick == $gettok($read(AutoID/nickname.txt,%i),1,46)) {
$gettok($read(AutoID/nickname.txt,%i),4,46) $gettok($read(AutoID/nickname.txt,%i),2,46)
}
}
}
}
}
on *:connect:{
if (%waid) {
var %l = $lines(AutoID/nickname.txt)
var %i = 0
while %i < %l {
inc %i
if ($network isin $gettok($read(AutoID/nickname.txt,%i),3,46)) {
if ($me == $gettok($read(AutoID/nickname.txt,%i),1,46)) {
$gettok($read(AutoID/nickname.txt,%i),4,46) $gettok($read(AutoID/nickname.txt,%i),2,46)
}
}
else if ($network isin $gettok($read(AutoID/nickname.txt,%i),3,46)) {
if ($me == $gettok($read(AutoID/nickname.txt,%i),1,46)) {
$gettok($read(AutoID/nickname.txt,%i),4,46) $gettok($read(AutoID/nickname.txt,%i),2,46)
}
}
}
}
}
raw 433:*:{
if (%waid) {
if ($status == connected) {
%newnick = $2
var %l = $lines(AutoID/nickname.txt)
var %i = 0
while %i < %l {
inc %i
if ($network isin $gettok($read(AutoID/nickname.txt,%i),3,46)) {
if (%newnick == $gettok($read(AutoID/nickname.txt,%i),1,46)) {
$gettok($read(AutoID/nickname.txt,%i),5,46) $chr(32) %newnick $gettok($read(AutoID/nickname.txt,%i),2,46)
timer8 1 3 nick $chr(32) %newnick
}
else timer9 1 1 pas.inclu1
return
}
}
}
if ($status == loggingon) {
if (!%nick.secours) { set %nick.secours WorldDMT_Ghost }
%ghostnick = $me
nick %nick.secours
var %l = $lines(AutoID/nickname.txt)
var %i = 0
while %i < %l {
inc %i
if ($network isin $gettok($read(AutoID/nickname.txt,%i),3,46)) {
if (%ghostnick == $gettok($read(AutoID/nickname.txt,%i),1,46)) {
$gettok($read(AutoID/nickname.txt,%i),5,46) $chr(32) %ghostnick $gettok($read(AutoID/nickname.txt,%i),2,46)
timer10 1 5 nick $chr(32) %ghostnick
return
}
else timer11 1 5 pas.inclu2
}
}
}
}
else timer12 1 1 stat.off
return
}
on *:load: {
echo -a - Chargement de l'Addon WautoIdentifyGhost V1.0 réussit
echo -a -
echo -a - Vous trouvez dans le menu bar WautoIdentifyGhost
echo -a -
echo -a - Cliquez dessus pour la configuration de l'Addon
}
on *:unload: {
echo -a - Désinstallation de l'Addon terminé avec succes
echo -a -
echo -a - merci d'avoir utilisé WautoIdentifyGhost V1.0
echo -a -
echo -a - WorldDMT
}
Conclusion :
Mettez le dossier AutoID dans votre dossier script
ensuite ouvrez le script et tapez /load -rs AutoID/AutoID.txt
NB:ne copiez pas le code dans votre remote en direct puisqu'il faut que le dossier qui contient 2 fichier AutoID.txt et Nickname.txt si non le script ne marchera plus
.
Vous n'êtes pas encore membre ?
inscrivez-vous, c'est gratuit et ça prend moins d'une minute !
Les membres obtiennent plus de réponses que les utilisateurs anonymes.
Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.
Le fait d'être membre vous permet d'avoir des options supplémentaires.