Macro Outlook 2010 ouverture de boîte

Question

Bonjour !

Je suis utilisateur professionnel de Outlook 2010 et je cherche à écrire une macro qui me permettrait d'accèder à la boîte pro d'un de mes collègues qui m'a mis en partage durant ses congés.
Je pourrais ainsi affecter cette macro à un bouton, et je gagnerais pas mal de temps; sinon je dois passer par le menu, retaper son nom etc....

Je n'ai pas de notion de programmation malheureusement; Quelqu'un aurait-il une idée de la rédaction de cette macro ? juste pour ouvrir la boîte de qqn d'autre

Merci beaucoup d'avance


nicolas

scartof · Answer

Bonjour

(Une réponse un peu tardive, ayant eu un problème similaire...)
Une possibilité serait peut-être de créer un nouveau groupe d&#8217;envoi réception (par exemple « blabla ») avec dans ce groupe un seul compte ayant les caractéristiques du compte de ton collègue (nom serveurs entrants et sortants&#8230;) puis ensuite de créer les macros suivantes :

Public Sub OuvrirCompte(NomCpte As String)
    'Envoyer & Recevoir pour le groupe (d'un ou plusieurs compte(s)) [NomCpte]
    Dim nsp As Outlook.NameSpace
    Dim sycs As Outlook.SyncObjects
    Dim syc As Outlook.SyncObject
    Dim i As Integer
    Set nsp = Application.GetNamespace("MAPI")
    Set sycs = nsp.SyncObjects
    For i = 1 To sycs.Count
        Set syc = sycs.Item(i)
        If syc.Name = NomCpte Then
            syc.Start
            Exit For
        End If
    Next
End Sub

Public Sub Ouvreblabla()
    Call OuvrirCompte("blabla")
End Sub

Ensuite affecter la macro "Ouvreblabla" à un bouton de la barre de lancement rapide.
Je l'ai fait pour ouvrir différentes boîtes mél depuis Outlook 2010 et ça marche correctement.

Scartof

cmcicg · Answer

En fait c'est beaucoup plus simple que ça.
Dans mon exemple, Christophe DUBOIS est le nom de votre collègue qui vous a partagé l'accès à sa boîte.

Sub Boite_Christophe()

Dim Boite As Folder, Christophe As Recipient, MonExploreur As Explorer
    
    Set Christophe = Outlook.Application.GetNamespace("MAPI").CreateRecipient("Christophe DUBOIS")
    Christophe.Resolve
    
    Set Boite = Outlook.Application.GetNamespace("MAPI").GetSharedDefaultFolder(Christophe, olFolderInbox)
    Set MonExploreur = Application.ActiveExplorer
    Set MonExploreur.CurrentFolder = Boite
    
    Set Christophe = Nothing
    Set Boite = Nothing
    Set MonExploreur = Nothing
    
End Sub

Nicolas

EDIT: Ajout de la coloration syntaxique.

Macro Outlook 2010 ouverture de boîte

2 réponses

Votre réponse

Discussions similaires