MenuStrip et item indexé

Question

Bonjour, 

Je cherche sous VB.net 2013 à créer un menu via MenuStrip comportant un sous-menu sous forme de tableau (ex. mnuItem()), dont la dimension est incrémentée dynamiquement dans le code. Avec VB6 et les premières versions de VB.Net, il suffisait d'affecter la valeur 0 à la propriété Index. Mais cette propriété a disparu avec MenuStrip. Existe-t-il une propriété équivalente ?
Sinon comment créer un tableau dynamique de sous-menus ?

Merci pour votre aide.

René

cs_Le Pivert · Answer

Bonjour,

comme ceci:

Public Class Form1
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        'création d'un nouveau menustrip
        Dim monmenu As New MenuStrip

'ajout d'un élément
        Dim menuitem As New ToolStripMenuItem
        menuitem.Text = "Fichier"

'ajout d'un sous-élément
        Dim itemOuvrir As New ToolStripMenuItem
        itemOuvrir.Text = "Ouvrir"
        'abonnement à l'événement click
        AddHandler itemOuvrir.Click, AddressOf item_Click
        menuitem.DropDownItems.Add(itemOuvrir)

'ajout d'un autre sous-élément
        Dim itemQuitter As New ToolStripMenuItem
        itemQuitter.Text = "Quitter"
        'abonnement à l'événement click
        AddHandler itemQuitter.Click, AddressOf item_Click
        menuitem.DropDownItems.Add(itemQuitter)

'ajout de l'élément au menustrip
        monmenu.Items.Add(menuitem)

'ajout du menustrip au formulaire
        Me.Controls.Add(monmenu)
    End Sub
    Private Sub item_Click(ByVal sender As Object, ByVal e As EventArgs)
        Dim monitem As ToolStripItem = DirectCast(sender, ToolStripItem)
        MessageBox.Show(monitem.Text)
    End Sub
End Class

cs_Le Pivert · Answer

Ajout d'un autre sous-élément:

   CType(monmenu.Items(0), ToolStripMenuItem).DropDownItems.Add("Exemple") 
 
Cacher un sous-élément:

CType(monmenu.Items(0), ToolStripMenuItem).DropDownItems(1).Visible = False

Mettre cette déclaration en dehors de la sub:

  Dim monmenu As New MenuStrip

cs_Le Pivert · Answer

Ajouter un sous menu avec ses sous menus:

  Dim c As ToolStripMenuItem
        c = CType(CType(monmenu.Items(0), ToolStripMenuItem).DropDownItems.Add("Nouveau menu"), ToolStripMenuItem)
        c.Name = "Nouveau menu"
        For lcoount As Integer = 1 To 2
            Dim innerItem As New ToolStripMenuItem()
            innerItem.Text = "Monmenu" & lcoount
            innerItem.Name = lcoount.ToString
            'abonnement à l'événement click
            AddHandler innerItem.Click, AddressOf item_Click
            c.DropDownItems.Add(innerItem)
        Next

Je pense que cela se rapproche plus de la demande

cs_Le Pivert · Answer

encore un exemple:

Public Class Form1

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim menu As New MenuStrip()
        For i As Integer = 0 To 2
            Dim item As New ToolStripMenuItem(String.Format("Main Item{0}", i.ToString()))
            For j As Integer = 0 To 7
                Dim innerItem As New ToolStripMenuItem(String.Format("Inner Menu Item {0}", j.ToString()))

'Give the DropDown Item a name so it can be identified in the handler sub
                innerItem.Name = item.Text & "_" & j.ToString

'Add a Click handler to the DropDown Item
                AddHandler innerItem.Click, AddressOf MenuItemClicked

item.DropDownItems.Add(innerItem)
            Next
            menu.Items.Add(item)
        Next
        Me.Controls.Add(menu)
    End Sub

Private Sub MenuItemClicked(ByVal sender As System.Object, ByVal e As System.EventArgs)
        Dim DropDownName As String = DirectCast(sender, ToolStripItem).Name
        MessageBox.Show(DropDownName)
    End Sub
End Class

MenuStrip et item indexé

4 réponses

Votre réponse

Discussions similaires